Adding service endpoint to subnets

[Alexprosp247]

I'm trying to add a service endpoint to my array of subnets in my virtual network module. However I get an error that the language expression property of "serviceEndpoints" doesn't exist. Not sure if its because the service endpoints property is an array so needs to be handled differently?

resource vnetdeployment 'Microsoft.Network/virtualNetworks@2023-05-01' = {
  name: vnetName
  location: location
  properties: {
    addressSpace: {
       addressPrefixes: [
        addressPrefix
       ]
    }
    subnets: [for subnet in subnets: {
      name: subnet.name
      properties: {
        addressPrefix: subnet.addressPrefix
        networkSecurityGroup: contains(subnet, 'networkSecurityGroupId') ? {
          id: subnet.networkSecurityGroupId
        } : null
        routeTable: contains(subnet, 'routeTableId') ? {
         id: subnet.routeTableId
        } : null
         natGateway: contains(subnet, 'natGatewayId') ? {
           id: subnet.natGatewayId
         } : null
         serviceEndpoints: subnet.serviceEndpoints
      }
    }]
  }}

Module File -

module vnetprodne10 'vnetconfig.bicep' = {
  name: 'vnet-prod-ne-10'
  scope: resourceGroup('rg-prodvnet-prod-ne-01')
  params: {
    location: rglocation1
    vnetName: 'vnet-prod-ne-10'
    addressPrefix: '10.10.0.0/16'
    subnets: [
      {
        name: 'snet-Prod10-prdsvr-ne-10'
        addressPrefix: '10.10.10.0/24'
        networkSecurityGroupId: nsgProd10prdsvr01.outputs.resourceId
        routeTableId: rtprod10hub.outputs.routeTableResourceId
      }
      {
        name: 'snet-Prod10-ctxvda-ne-10'
        addressPrefix: '10.10.20.0/24'
        networkSecurityGroupId: nsgProd10ctxvda01.outputs.resourceId
        routeTableId: rtprod10hub.outputs.routeTableResourceId
        natGateway: ngvnetprodne01.outputs.natGatewayResourceId
        serviceEndpoints: [
          {
            service: 'Microsoft.Storage'
          }
        ]
      }
    ]
    diagnosticWorkspaceId: logworkspace.id
  }
}

[kevball2]

You need to add conditional checks for the serviceEndpoints property. Your first subnet does not include that property, so the validation is failing. You can use safe-dereferences to solve this:

 subnets: [for subnet in subnets: {
      name: subnet.name
      properties: {
        addressPrefix: subnet.addressPrefix
        networkSecurityGroup: contains(subnet, 'networkSecurityGroupId') ? {
          id: subnet.networkSecurityGroupId
        } : null
        routeTable: contains(subnet, 'routeTableId') ? {
         id: subnet.routeTableId
        } : null
         natGateway: contains(subnet, 'natGatewayId') ? {
           id: subnet.natGatewayId
         } : null
         serviceEndpoints: subnet.?serviceEndpoints ?? []
      }
    }]

With these checks, if serviceEndpoints does not exist on a subnet, then a empty array will be passed instead.

[Alexprosp247]

Can confirm that's worked. Thanks very much :)