Automation Account - Attaching Job Schedule to Runbook

[jmann8719]

Hello! I've not been able to track down an answer for this query, so hoping someone can help.

I'm creating a Azure Automation Account, Runbook (PowerShell), Schedule and Job Schedule Resources in my template.

The deployment succeeds apart from the Job Schedule, returning 'Bad Request' it's unable to retrieve the Runbook or Schedule Value.

Bicep is requesting the values as String but I am not sure how to present this as I have tried specifying the names manually with no joy.

Has anyone successfully created an Automation Runbook and automatically linked it with a Schedule?

Thank you

resource automationaccount 'Microsoft.Automation/automationAccounts@2022-08-08' = {
  name: '<Automation Account Name>'
  identity: {
    type: 'SystemAssigned'
  }
  properties: {
    sku: {
      name: 'Basic'
    }
  }
}

resource child_automationaccount_runbook 'Microsoft.Automation/automationAccounts/runbooks@2022-08-08'= {
  name: '<Runbook Name>'
  parent: automationaccount
  properties: {
    runbookType: 'PowerShell'
    publishContentLink: {
      uri: 'https://raw.githubusercontent.com/...'
    }
  }
}

resource child_automationaccount_schedule 'Microsoft.Automation/automationAccounts/schedules@2022-08-08' = {
  name: '<Schedule Name>'
  parent: automationaccount
  properties: {
    startTime: ''
    interval: any(1)
    frequency: 'Hour'
  }
}

resource child_automationaccount_jobschedule 'Microsoft.Automation/automationAccounts/jobSchedules@2022-08-08' = {
  name: '<Job Schedule Name>'
  parent: automationaccount
  properties: {
    runbook: {
      name: child_automationaccount_runbook
    }
    schedule: {
      name: child_automationaccount_schedule
    }
  }
}

[jmann8719]

Managed to resolve this after finding the Job Schedule Name value must be a GUID.

This is the code that worked for me:

resource child_automationaccount_jobschedule 'Microsoft.Automation/automationAccounts/jobSchedules@2022-08-08' = {
  name: guid(resourceGroup().id)
  parent: automationaccount
  properties: {
    runbook: {
      name: child_automationaccount_runbook.name
    }
    schedule: {
      name: child_automationaccount_schedule.name
    }
  }
}