-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
216 lines (187 loc) · 6.83 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
group = 'de.huk.example'
version = '1.0-SNAPSHOT'
buildscript {
dependencies {
classpath 'net.wasdev.wlp.gradle.plugins:liberty-gradle-plugin:1.0'
classpath files('gradle/wlp-anttasks.jar')
classpath 'org.cloudfoundry:cf-gradle-plugin:1.1.2'
}
}
apply plugin: 'war'
apply plugin: 'liberty'
apply plugin: 'cloudfoundry'
sourceCompatibility = 1.8
targetCompatibility = 1.8
def libertyVersion = '17.0.0.1'
compileJava.options.encoding = 'UTF-8'
ext {
// Liberty server properties
wlpServerName = 'LibertyProjectServer'
serverDirectory = "${buildDir}/wlp/usr/servers/${wlpServerName}"
testServerHttpPort = 9080
testServerHttpsPort = 9443
// This is set in the ibm-web-ext.xml file
warContext = 'myLibertyApp'
appName = 'LibertySwagger'
packageFile = "${project.buildDir}/${appName}.zip"
packagingType = 'usr'
// Cloud Foundry/Bluemix properties
// This is the host for your app in Bluemix and what it will be called in the dashboard.
cfHost = appName
cfContext = 'mybluemix.net'
cfTarget = 'https://api.ng.bluemix.net'
cfSpace = 'dev'
cfContextRoot = "${cfHost}.${cfContext}/${warContext}"
// The Cloud Foundry or Bluemix organization, username and password can be entered here.
// cfOrg = ''
// cfUsername = ''
// cfPassword = ''
}
dependencies {
testCompile 'junit:junit:4.12'
testCompile 'org.apache.cxf:cxf-rt-rs-client:3.1.1'
testCompile 'org.glassfish:javax.json:1.0.4'
providedCompile 'net.wasdev.wlp.starters.swagger:provided-pom:0.0.3'
runtime 'net.wasdev.wlp.starters.swagger:runtime-pom:0.0.3'
}
test {
reports.html.destination = file("$buildDir/reports/unit")
reports.junitXml.destination = file("$buildDir/test-results/unit")
exclude '**/it/**'
}
task integrationTest(type: Test) {
group 'Verification'
description 'Runs the integration tests.'
reports.html.destination = file("$buildDir/reports/it")
reports.junitXml.destination = file("$buildDir/test-results/it")
include '**/it/**'
exclude '**/unit/**'
systemProperties = ['liberty.test.port': testServerHttpPort, 'war.name': warContext, 'running.bluemix': 'false', 'cf.context.root': cfContextRoot ]
}
gradle.taskGraph.whenReady { graph ->
if (graph.hasTask(cfPush)) {
integrationTest.systemProperties['running.bluemix'] = 'true'
}
}
task copyConfigSnippetsToServer {
doLast {
def serverSnippetCopySpecs = []
configurations.runtime.resolvedConfiguration.getFirstLevelModuleDependencies().each {
addServerSnippetDependencies(it, serverSnippetCopySpecs)
}
copy {
into "${serverDirectory}/configDropins/defaults"
with serverSnippetCopySpecs.toArray(new CopySpec[serverSnippetCopySpecs.size()])
}
}
}
task printMessageAboutRunningServer {
doLast {
println "The server is now running at http://localhost:${testServerHttpPort}/${warContext}"
println "To stop the server run 'gradle libertyStop'"
}
}
def addServerSnippetDependencies(resolvedDependency, copySpecs) {
if ("server-snippet".equals(resolvedDependency.getModuleName())) {
resolvedDependency.getModuleArtifacts().each { artifact ->
copySpecs.add(copySpec {
from artifact.getFile()
rename { String fileName ->
resolvedDependency.getModuleGroup() + fileName
}
})
}
}
resolvedDependency.getChildren().each {
addServerSnippetDependencies(it, copySpecs)
}
}
task publishServerConfig(type: Copy) {
from 'src/main/liberty/config/server.xml'
into serverDirectory
}
task publishWar(type: Copy) {
from(war)
into("${serverDirectory}/dropins")
}
task createServerBootstrap() {
outputs.file("${serverDirectory}/bootstrap.properties")
doLast {
def bootstrapProperties = file("${serverDirectory}/bootstrap.properties")
if (!bootstrapProperties.exists()) {
bootstrapProperties << "default.http.port=${testServerHttpPort}\ndefault.https.port=${testServerHttpsPort}"
}
}
}
// Use Gradle liberty plugin
// Docu: https:/WASdev/ci.gradle
liberty {
install {
runtimeUrl = project.ext['huk.nexus.url'] + "/com/ibm/websphere/appserver/runtime/wlp-javaee7/${libertyVersion}/wlp-javaee7-${libertyVersion}.zip"
username = project.ext['huk.nexus.username'] // Add here your Nexus User Token
password = project.ext['huk.nexus.passwd'] // Add here your Nexus User Password
}
println "Liberty server version ${libertyVersion} installed"
serverName = wlpServerName
packageLiberty {
archive = packageFile
include = packagingType
}
features {
name = ['apiDiscovery-1.0']
acceptLicense = true
}
}
task libertyStartTestServer(type: net.wasdev.wlp.gradle.plugins.tasks.StartTask){
description 'Starts the WebSphere Liberty Profile server for testing.'
logging.level = LogLevel.INFO
}
task checkBluemixPropertiesSet() {
doLast {
checkPropertySet('cfOrg')
checkPropertySet('cfUsername')
checkPropertySet('cfPassword')
}
}
task printBluemixProperties(dependsOn: 'checkBluemixPropertiesSet') {
doLast {
println "Running bluemix profile with the following properties:\n" +
"\tcf.target=${cfTarget}\n" +
"\tcf.space=${cfSpace}\n" +
"\tcf.org=${cfOrg}\n" +
"\tcf.username=${cfUsername}\n" +
"The application will be accessed at context root ${cfContextRoot}"
}
}
def checkPropertySet(propertyName) {
if (!project.hasProperty(propertyName)) {
throw new GradleException("The ${propertyName} property must be provided to run the cfPush task, this can be supplied on the command line with -P${propertyName}=<value>.")
}
}
cloudfoundry {
target = cfTarget
if (project.hasProperty('cfOrg')) {
organization = cfOrg
}
space = cfSpace
file = file(packageFile)
memory = 512
appName = cfHost
}
tasks.create('setupServer')
check.dependsOn 'integrationTest'
setupServer.dependsOn 'installLiberty', 'createServerBootstrap', 'publishServerConfig', 'copyConfigSnippetsToServer', 'publishWar'
createServerBootstrap.mustRunAfter 'installLiberty'
publishServerConfig.mustRunAfter 'installLiberty'
copyConfigSnippetsToServer.mustRunAfter 'installLiberty'
publishWar.mustRunAfter 'installLiberty'
publishWar.dependsOn 'war'
libertyStart.dependsOn 'setupServer'
integrationTest.dependsOn 'libertyStartTestServer', 'testClasses'
integrationTest.finalizedBy 'libertyStop'
libertyStartTestServer.dependsOn 'setupServer'
assemble.dependsOn 'libertyPackage'
libertyPackage.dependsOn 'setupServer'
cfPush.dependsOn 'printBluemixProperties'
integrationTest.mustRunAfter 'cfPush'
libertyStart.finalizedBy 'printMessageAboutRunningServer'