Add support for Dagger dependency injection

[drigz]

I tried to use the annotation processor support from #93 to use Dagger but I got the error java.lang.ClassNotFoundException: com.google.common.collect.Multimap from the annotation processor when compiling.

My config:

  com.google.dagger:
    dagger-compiler:
      lang: java
      version: "2.11"
      processorClasses: ["dagger.internal.codegen.ComponentProcessor"]

This generates the following rules in java/com/google/dagger/BUILD: (adjusted for brevity)

java_library(
    name = "dagger",
    exports = ["//external:jar/com/google/dagger/dagger"],
)

java_library(
    name = "dagger_compiler",
    exported_plugins = [":dagger_compiler_plugin"],
    exports = ["//external:jar/com/google/dagger/dagger_compiler"],
    runtime_deps = [
        ":dagger",
        ":dagger_producers",
        "//third_party/java/com/google/code/findbugs:jsr305",
        "//third_party/java/com/google/googlejavaformat:google_java_format",
        "//third_party/java/com/google/guava",
        "//third_party/java/com/squareup:javapoet",
        "//third_party/java/javax/inject:javax_inject",
    ],
)

java_plugin(
    name = "dagger_compiler_plugin",
    processor_class = "dagger.internal.codegen.ComponentProcessor",
    deps = ["//external:jar/com/google/dagger/dagger_compiler"],
)

However, this doesn't work as the annotation processor depends on the dagger compiler, which in turn has dependencies. In other words, :dagger_compiler_plugin should depend on :dagger_compiler, not //external:jar/com/google/dagger/dagger_compiler. It's also missing generates_api = True. The correct rules are:

java_library(
    name = "dagger",
    exports = ["//external:jar/com/google/dagger/dagger"],
)

java_library(
    name = "dagger_compiler",
    exports = ["//external:jar/com/google/dagger/dagger_compiler"],
    runtime_deps = [
        ":dagger",
        ":dagger_producers",
        "//third_party/java/com/google/code/findbugs:jsr305",
        "//third_party/java/com/google/googlejavaformat:google_java_format",
        "//third_party/java/com/google/guava",
        "//third_party/java/com/squareup:javapoet",
        "//third_party/java/javax/inject:javax_inject",
    ],
)

java_plugin(
    name = "dagger_compiler_plugin",
    generates_api = True,
    processor_class = "dagger.internal.codegen.ComponentProcessor",
    deps = [":dagger_compiler"],
)

java_library(
    name = "dagger_with_compiler",
    exported_plugins = [":dagger_compiler_plugin"],
    exports = [":dagger"],
)

Workaround

• Remove the processorClasses setting from dependencies.yaml to avoid the incorrect plugin definition.
• Add these build rules, eg to //src/java:

java_plugin(
    name = "dagger_compiler_plugin",
    generates_api = True,
    processor_class = "dagger.internal.codegen.ComponentProcessor",
    deps = ["//third_party/java/com/google/dagger:dagger_compiler"],
)

java_library(
    name = "dagger_with_compiler",
    exported_plugins = [":dagger_compiler_plugin"],
    exports = ["//third_party/java/com/google/dagger"],
)

• Depend on :dagger_with_compiler where needed.

It's probably also possible to reuse the Bazel BUILD files from the Dagger repository, but I haven't tried this yet.

[hsyed]

neverlink and testonly also need to be added

[johnynek]

happy to accept a PR to fix this up.

Sorry it isn't working currently.