forked from superbrothers/zsh-kubectl-prompt
-
Notifications
You must be signed in to change notification settings - Fork 0
/
kubectl.zsh
67 lines (54 loc) · 2.07 KB
/
kubectl.zsh
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
setopt prompt_subst
autoload -U add-zsh-hook
function() {
local namespace separator modified_time_fmt
# Specify the separator between context and namespace
zstyle -s ':zsh-kubectl-prompt:' separator separator
if [[ -z "$separator" ]]; then
zstyle ':zsh-kubectl-prompt:' separator '/'
fi
# Display the current namespace if `namespace` is true
zstyle -s ':zsh-kubectl-prompt:' namespace namespace
if [[ -z "$namespace" ]]; then
zstyle ':zsh-kubectl-prompt:' namespace true
fi
# Check the stat command because it has a different syntax between GNU coreutils and FreeBSD.
if stat --help >/dev/null 2>&1; then
modified_time_fmt='-c%y' # GNU coreutils
else
modified_time_fmt='-f%m' # FreeBSD
fi
zstyle ':zsh-kubectl-prompt:' modified_time_fmt $modified_time_fmt
}
add-zsh-hook precmd _zsh_kubectl_prompt_precmd
function _zsh_kubectl_prompt_precmd() {
local kubeconfig updated_at now context namespace ns separator modified_time_fmt
kubeconfig="$HOME/.kube/config"
if [[ -n "$KUBECONFIG" ]]; then
kubeconfig="$KUBECONFIG"
fi
zstyle -s ':zsh-kubectl-prompt:' modified_time_fmt modified_time_fmt
if ! now="$(stat -L $modified_time_fmt "$kubeconfig" 2>/dev/null)"; then
ZSH_KUBECTL_PROMPT="kubeconfig is not found"
return 1
fi
zstyle -s ':zsh-kubectl-prompt:' updated_at updated_at
if [[ "$updated_at" == "$now" ]]; then
return 0
fi
zstyle ':zsh-kubectl-prompt:' updated_at "$now"
if ! context="$(kubectl config current-context 2>/dev/null)"; then
ZSH_KUBECTL_PROMPT="current-context is not set"
return 1
fi
zstyle -s ':zsh-kubectl-prompt:' namespace namespace
if [[ "$namespace" != true ]]; then
ZSH_KUBECTL_PROMPT="${context}"
return 0
fi
ns="$(kubectl config view -o "jsonpath={.contexts[?(@.name==\"$context\")].context.namespace}")"
[[ -z "$ns" ]] && ns="default"
zstyle -s ':zsh-kubectl-prompt:' separator separator
ZSH_KUBECTL_PROMPT="${context}${separator}${ns}"
return 0
}