Build native executable artifacts

buildSrc/build.gradle.kts

@@ -4,4 +4,8 @@ plugins {
 repositories {
  jcenter()
 }
-
+
+dependencies {
+ // Needed by the script 'canteen.gradle'
+ implementation("com.google.guava:guava:27.0.1-jre")
+}

canteen.gradle

@@ -0,0 +1,81 @@
+// The following dependency needs to exist on the 'buildscript' classpath
+// 'com.google.guava:guava:27.0.1-jre'
+// It is currently added via the buildSrc project
+import com.google.common.io.ByteStreams
+
+// Native artifact generation based off of
+// https:/salesforce/grpc-java-contrib/tree/master/canteen
+
+def platforms = ["osx-x86_64", "linux-x86_64", "windows-x86_64"]
+
+Task bootJarTask = tasks.getByName("bootJar")
+File bootJarFile = bootJarTask.archiveFile.get().asFile
+
+platforms.each { platform ->
+
+ // Resolve the canteen bootstrap artifact
+ Configuration config = project.configurations.create("canteenBootstrapLocator_$platform") {
+ visible = false
+ transitive = false
+ extendsFrom = []
+ }
+ Map<String, String> notation = [
+ group: "com.salesforce.servicelibs",
+ name: "canteen-bootstrap",
+ version: "1.0.0",
+ classifier: platform,
+ ext: "exe",
+ ]
+ Dependency dep = project.dependencies.add(config.name, notation)
+ File bootstrapFile = config.fileCollection(dep).singleFile
+ File destinationArtifactFile = new File(bootJarTask.destinationDirectory.get().asFile,
+ bootJarFile.name.replace("jvm8.jar", platform + ".exe"))
+
+ // Create task to copy the original jar and embed the
+ // canteen bootstrap executable for the target platform
+ Task canteenTask = task("canteenArtifact_$platform"){
+ group = "canteen"
+ dependsOn("bootJar")
+ // Add files for UP-TO-DATE checks
+ inputs.files(bootJarFile)
+ outputs.files(destinationArtifactFile)
+ doLast {
+ // Build the bootstrap file
+ OutputStream targetStream = new FileOutputStream(destinationArtifactFile)
+ InputStream bootstrapStream = new FileInputStream(bootstrapFile)
+ ByteStreams.copy(bootstrapStream, targetStream);
+ InputStream sourceStream = new FileInputStream(bootJarFile)
+ ByteStreams.copy(sourceStream, targetStream);
+ targetStream.flush()
+ targetStream.close()
+ sourceStream.close()
+ bootstrapStream.close()
+ destinationArtifactFile.setExecutable(true);
+ }
+ }
+
+ artifacts {
+ archives(destinationArtifactFile) {
+ builtBy canteenTask
+ classifier platform
+ }
+ }
+
+ publishing {
+ publications {
+ mavenPublication(MavenPublication) {
+ artifact(destinationArtifactFile.absolutePath) {
+ builtBy canteenTask
+ classifier platform
+ }
+ }
+ }
+ }
+}
+
+task buildCanteenArtifacts{
+ group = "canteen"
+ platforms.each { platform ->
+ dependsOn("canteenArtifact_$platform")
+ }
+}

example-project/build.gradle

@@ -89,7 +89,7 @@ protobuf {
  plugins {
  grpc { artifact = "io.grpc:protoc-gen-grpc-java:${versions.grpc}" }
  kroto {
- artifact = "com.github.marcoferrer.krotoplus:protoc-gen-kroto-plus:${versions.krotoplus}:jvm8@jar"
+ path = "${rootDir}/../protoc-gen-kroto-plus/build/libs/protoc-gen-kroto-plus-${versions.krotoplus}-${osdetector.classifier}.exe"
  }
  }
 

kroto-plus-coroutines/build.gradle

@@ -63,14 +63,13 @@ protobuf {
  //noinspection GroovyAssignabilityCheck
  plugins {
  coroutines {
- path = "${rootProject.projectDir}/protoc-gen-grpc-coroutines/build/libs/protoc-gen-grpc-coroutines-${project.version}-jvm8.jar"
+ path = "${rootProject.projectDir}/protoc-gen-grpc-coroutines/build/libs/protoc-gen-grpc-coroutines-${project.version}-${osdetector.classifier}.exe"
  }
  }
 
  generateProtoTasks {
-
  all().each{ task ->
- task.dependsOn ':protoc-gen-grpc-coroutines:bootJar'
+ task.dependsOn ':protoc-gen-grpc-coroutines:buildCanteenArtifacts'
  task.builtins {
  remove java
  }

protoc-gen-grpc-coroutines/build.gradle

@@ -31,6 +31,8 @@ bootJar {
  }
 }
 
+apply from: "${rootProject.projectDir}/canteen.gradle"
+
 jar.enabled = true
 
 artifacts {

protoc-gen-kroto-plus/build.gradle

@@ -83,6 +83,8 @@ bootJar {
  }
 }
 
+apply from: "${rootProject.projectDir}/canteen.gradle"
+
 jar.enabled = true
 
 artifacts {

protoc-gen-kroto-plus/generator-tests/build.gradle

@@ -42,7 +42,7 @@ protobuf {
  //noinspection GroovyAssignabilityCheck
  plugins {
  kroto {
- path = "${rootProject.projectDir}/protoc-gen-kroto-plus/build/libs/protoc-gen-kroto-plus-${project.version}-jvm8.jar"
+ path = "${rootProject.projectDir}/protoc-gen-kroto-plus/build/libs/protoc-gen-kroto-plus-${project.version}-${osdetector.classifier}.exe"
  }
  }
 
@@ -51,7 +51,7 @@ protobuf {
 
  all().each{ task ->
  task.inputs.files krotoConfig
- task.dependsOn ':protoc-gen-kroto-plus:bootJar'
+ task.dependsOn ':protoc-gen-kroto-plus:buildCanteenArtifacts'
 
  task.plugins {
  kroto {