-
-
Notifications
You must be signed in to change notification settings - Fork 2
/
pilasm.e
5194 lines (5106 loc) · 223 KB
/
pilasm.e
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
--
-- pilasm.e
--
-- Process ilasm{} (inline assembly) constructs.
-- Included by and called from pmain.e
--
-- This is a "bare minimum to get by" assembler:
-- There is no real intention of ever implementing "all" x86 opcodes,
-- instead keep it simple(ha) and implement things as actually needed.
-- As a quick example, if you have some assembly experience, you will
-- likely slap down an "enter" and "leave", which will cause an error.
-- My first question will simply be "why?", and I will simply reject
-- "because that's what I've always done". Not that I will object to
-- someone else adding (and thoroughly testing) those instructions
-- (which may afaIac just be "skip and emit no code").
--
-- If you have not yet read (and understood) some of the ilASM constructs
-- in the builtins directory, then there really is no point reading this
-- any further until you have. No, I mean it, go and read some NOW!
-- Any will do: pHeap.e, pStack.e, pfileioN.e, there are dozens of them,
-- VM\pLen.e, VM\pSleep.e, VM\puts1.e are relatively simple starters.
--
-- There are quite a few "?9/0" in this source; I have quickly run down
-- this file marking (most of) them as either
-- -- sanity check (should never trigger)
-- or -- placeholder for more code
-- The general idea, of course, is to locate the latter asap (or in fact
-- immediately) and a quick search for similar code coupled with a few
-- minutes experimentation in eg OllyDbg to get examples of the binary
-- needed (or if you prefer a trawl through the intel docs) should mean
-- it is relatively quick to add new bits and pieces as needed. ymmv.
-- Or of course a ?9/0 triggering might be an obvious typo in your code
-- and/or an indication where some better error messages are required.
--
-- TIP: edit binary such as 2A448A 08 (sub al,byte[edx+ecx*4+8])
-- to #2A #44 #8A d8
-- [in Edita] CtrlShiftB*3 0o52 0o104 0o212 d8
-- and insert a leading 0: 0o052 0o104 0o212 d8
-- then spot the patterns: 0o0m2 0o1r4 0osib d8
-- (very well done at home if you followed that on first reading!)
--
-- While there is no real guarantee on the rest of Phix, there is even
-- less of one here. Obviously comments such as
-- -- 0o211 0o0ds -- mov [dst],src
-- are hints at what we are trying to achieve, rather than 100% truth.
-- (I done me best guv, but I'd lay out serious money on someone being
-- able to find a glaring mistake in at least one or twelve of them.)
-- (Oh, I have almost certainly confused xrm and sib at several points
-- throughout this code, but only in terms of the local integer used.)
--
-- You should NEVER trust that ilasm constructs output the right code;
-- always carefully inspect the list.asm from a "p -d" and if in doubt
-- use OllyDbg/FDBG or similar and see what that (dis)assembles. Phix
-- uses #ilASM as "the last resort" - quite prevalent in builtins/VM,
-- occasionally in library code, but almost never in application code.
--
-- Note: s5 is maintained as "sequence of integer", via a #isginfo
-- ==== statement in pmain.e; here you must always explicitly use
-- intermediate integers (with the implicit type checking it
-- involves), eg (assuming "object p2details" and "integer k")
-- instead of:
-- s5 &= p2details
-- do (eg):
-- k = and_bits(p2details,#FF)
-- s5 &= k
-- or maybe just:
-- s5 &= and_bits(p2details,#FF)
--
-- Note2: Be careful not to output any calculated bytes >=#100, as
-- ===== such will be misinterpreted by scanforShortJmp/blurph()
-- in pemit.e as isOpCode etc and most likely crash. If you
-- do get any such errors, and have recently modified this,
-- well, now you know what to look for first.
--
-- TIP: If you get an indecipherable error via Aborp(), try changing
-- === it to Aborq(). It clearly isn't a blanket change, just those
-- that involve/occur after (eg) getCh() not getToken(). If it
-- doesn't help, please change it back. Another thing to try is
-- manually setting tokline and tokcol before calling Aborp().
-- Obviously such require either "p -cp" or "p p" to test.
-- Errors and Omissions (beyond the ?9/0 already mentioned)
-- ====================
-- You cannot obtain a hll var address "inline"; lea it first:
--
-- mov eax,[stdin] -- OK, var contents
-- push [stdin] -- OK, var contents
-- push stdin -- illegal, var address <-- ***
-- lea eax,[stdin] -- \ instead use this
-- push eax -- / sort of pairing.
-- lea eax,[p1] -- OK, maps to [ebp+nn]
-- mov eax,p1 -- meaningless/impossible in all senses
--
-- It could be possible to introduce some new syntax to half-
-- solve(or address, geddit) this such as:
--
-- mov eax,$stdin
--
-- but there would still be no equivalent for locals/params
-- (because there is no such machine code instruction).
-- Another way to say this is that hll vars must be accessed
-- via "[name]" (ie contents) not "name" (ie address).
--
-- If you have say "constant MODE = 4" then you can reference
-- it directly, eg "push MODE" is the same as "push 4" (with
-- an assumed dword qualifier). However if you have a runtime
-- assigned constant such as "constant MAIN = create(Window.."
-- then, I hope this is obvious, you have to load it using eg
-- "push [MAIN]" instead of "push MAIN".
--
-- There are very few SSE (etc) instructions. My strategy is to
-- translate working FASM examples, as and when I find them.
--
-- Of COURSE I use Intel syntax. No SANE person would ever pick
-- AT&T syntax unless constrained by other closed source or way
-- too difficult to modify tools further down the chain. But as
-- there are no further tools, Intel syntax is FAR easier, both
-- to read AND write than AT&T, and if you disagree then pffft!
--
without trace
-- #ilasm label tables:
sequence lblchain, -- backpatch chain into s5 for final fixup
lblpos, -- label offset (length(s5) at definition)
lblopa, -- opAsm addr (to grab actual x86 addr)
lblcol, -- for error reporting
lblline, -- ""
lblttidx, -- to clear tt[idx+EQ] when done
lblused -- flag indicating whether label used, avoids
-- warnings for eg:
-- if DEBUG then -- (hence emitON=0)
-- #ilasm{...,isJmp,0,0,:lbl,...}
-- end if
-- ...
-- #ilasm{::lbl}
-- Naturally if emitON is the other way round,
-- jmp emitted but label not, it is an error.
-- verify that the compiler is setting these as "sequence of integer":
--/**/ #isginfo{lblchain,0b0100,MIN,MAX,integer,-2}
lblchain = {}
lblpos = {}
lblopa = {}
lblcol = {}
lblline = {}
lblttidx = {}
lblused = {}
integer ridState = 0 -- bits:
-- #0 initial value
-- #1 routine_id processed
-- #2 $_Ltot processed
-- #4 $_il processed
-- valid transtions (of ridState):
-- (mov edx,)routine_id(): 0 -> 1
-- (mov ecx,)$_Ltot: 1 -> 3, 5 -> 0
-- (jmp) $_il: 1 -> 5, 3 -> 0
integer ridLtot, ridN
function ridStateError()
string errmsg
if and_bits(ridState,1)=0 then
errmsg = "missing routine_id??" -- (should never happen)
elsif and_bits(ridState,2)=0 then
errmsg = "missing $_Ltot"
elsif and_bits(ridState,4)=0 then
errmsg = "missing $_il"
end if
return errmsg
end function
global procedure label_fixup()
--
-- Complete backpatching of any #ilasm labels, and
-- emit errors/warnings for undefined/unused labels.
-- Called direct from ilasm() for top_level code,
-- and/or from end of DoRoutineDef() for routines.
-- A second round of ilasm label fixups occurs at
-- the end of ilxlate() in pilxl.e, btw.
-- For more details, see design notes in pops.e.
--
integer lblidx -- index to lblchain..lblused
integer lblposi -- copy of lblpos[i]
integer lblopai -- copy of lblopa[i]
integer lblbp -- label backpatch work var
integer tmp
for i=1 to length(lblchain) do
lblidx = lblttidx[i]
tt[lblidx+EQ] = 0 -- (dropscope)
lblbp = lblchain[i]
if lblbp then
lblposi = lblpos[i]
if lblposi!=-1 then
lblopai = lblopa[i]
while 1 do
tmp = s5[lblbp]
s5[lblbp-1] = lblopai -- link to containing opAsm
s5[lblbp] = lblposi -- il offset of label definition
if not tmp then exit end if
lblbp = tmp
end while
else
tokline = lblline[i]
tokcol = lblcol[i]
Aborp(getname(lblidx,-3)&" is not defined")
end if
elsif not lblused[i] then -- (isJmp may be under emitON=0)
Warn(getname(lblidx,-3)&" is not used",lblline[i],lblcol[i],0)
end if
end for
lblchain = {}
lblpos = {}
lblopa = {}
lblcol = {}
lblline = {}
lblttidx = {}
lblused = {}
end procedure
--constant m4 = allocate(4),
-- m44 = {m4,4},
-- m22 = {m4,2}
procedure apnds5dword(atom v)
-- break up a dword constant into 4 bytes
string s
atom m4 = allocate(4)
poke4(m4, v) -- faster than doing divides etc. (idea from database.e)
s = peek({m4,4})
free(m4)
for i=1 to 4 do
s5 &= s[i]
end for
end procedure
--/*
procedure apnds5qword(atom v)
-- break up a dword constant into 8 bytes (will not work for >53 significnat bits, eg #8000000000000001 is a definite no-no)
--string s
poke4(m4, and_bits(v,#FFFFFFFF))
s5 &= peek(m44)
poke4(m4, floor(v/#100000000))
s5 &= peek(m44)
end procedure
--*/
procedure apnds5word(integer v)
-- break up a dword constant into 2 bytes
string s
atom m2 = allocate(2)
poke2(m2, v) -- faster than doing divides etc. (idea from database.e)
-- s = peek2u(m22)
s = peek({m2,2})
free(m2)
for i=1 to 2 do
s5 &= s[i]
end for
end procedure
-- permission bits, further documented in get_operand().
constant P_REG = #0001,
P_MEM = #0002,
P_RAW = #0003, -- raw data section offset (eg mov rax,[ds+8] -- symtabptr)
P_LBL = #0004,
P_IMM = #0008,
P_VAR = #0010, -- [hllvar] (result)
P_GBL = #0020, -- global label (result)
P_SEG = #0040, -- segment register [for tls handling] --DEV
P_FPU = #0080,
P_XMM = #0100,
P_RID = #0200,
P_RM = or_bits(P_REG,P_MEM),
P_RI = or_bits(P_REG,P_IMM),
P_LI = or_bits(P_LBL,P_IMM),
P_RLI = or_bits(P_REG,P_LI),
P_RMLI = or_bits(P_RM,P_LI),
P_RMLIS = or_bits(P_RMLI,P_SEG),
P_ML = or_bits(P_MEM,P_LBL),
P_MLS = or_bits(P_ML,P_SEG),
P_MV = or_bits(P_MEM,P_VAR),
P_XMMM = or_bits(P_XMM,P_MEM)
constant REG32 = {T_eax,T_ecx,T_edx,T_ebx,T_esp,T_ebp,T_esi,T_edi},
REG16 = {T_ax,T_cx,T_dx,T_bx,T_sp,T_bp,T_si,T_di},
REG8 = {T_al,T_cl,T_dl,T_bl,T_ah,T_ch,T_dh,T_bh},
R64 = {T_rax,T_rcx,T_rdx,T_rbx,T_rsp,T_rbp,T_rsi,T_rdi,T_r8,T_r9,T_r10,T_r11,T_r12,T_r13,T_r14,T_r15},
R32 = {T_r8d,T_r9d,T_r10d,T_r11d,T_r12d,T_r13d,T_r14d,T_r15d},
R16 = {T_r8w,T_r9w,T_r10w,T_r11w,T_r12w,T_r13w,T_r14w,T_r15w},
R8l = {T_r8l,T_r9l,T_r10l,T_r11l,T_r12l,T_r13l,T_r14l,T_r15l},
R8b = {T_spl,T_bpl,T_sil,T_dil,T_r8b,T_r9b,T_r10b,T_r11b,T_r12b,T_r13b,T_r14b,T_r15b}
--/*
constant r8={"al","cl","dl","bl","ah","ch","dh","bh","r8l","r9l","r10l","r11l","r12l","r13l","r14l","r15l"},
--DEV r8b={"al","cl","dl","bl","spl","bpl","sil","dil","r8b","r9b","r10b","r11b","r12b","r13b","r14b","r15b"}, -- (if there is a rex prefix? (#40 will do))
-- (r8b..r15b are exactly the same as r8l..r15l)
r8l={"spl","bpl","sil","dil"},
r16={"ax","cx","dx","bx","sp","bp","si","di","r8w","r9w","r10w","r11w","r12w","r13w","r14w","r15w"},
--*/
constant XMM = {T_xmm0,T_xmm1,T_xmm2,T_xmm3,T_xmm4,T_xmm5,T_xmm6,T_xmm7}
integer Z64 -- like/copy of pglobals.e/X64, but with ilASM{[PE64]} etc applied. (should ==X64 when emitON=true, I think)
-- comment 19/11/14: I think Z64 should be used to control parsing, X64 to control binary output (when emitON=true!).
constant SIZES = {T_byte,T_word,T_dword,T_qword,T_tbyte,T_tword},
SIZE = { 1, 2, 4, 8, 10, -10}
constant FREG = {T_st0, T_st1, T_st2, T_st3, T_st4, T_st5, T_st6, T_st7}
global procedure Aborq(sequence msg)
tokline = line
tokcol = col
Aborp(msg)
end procedure
function get_offset(integer res, integer sign)
-- common code for get_mem() and get_operand()
--integer res = 0
integer N
sequence symtabN
if not find(sign,{-1,0,1}) then ?9/0 end if -- (-,*,+)
while 1 do
if toktype=LETTER then
N = InTable(InAny)
if N<=0 then Undefined() end if
symtabN = symtab[N]
if symtabN[S_vtype]!=T_integer
or symtabN[S_NTyp]!=S_Const
or not symtabN[S_Init] then
Aborp("illegal")
end if
if sign=0 then
res *= symtabN[S_value]
else
res += sign*symtabN[S_value]
end if
elsif toktype=DIGIT then
if sign=0 then
res *= TokN
else
res += sign*TokN
end if
else
Aborp("unrecognised")
end if
if Ch='+' then
getToken()
getToken()
sign = 1
elsif Ch='-' then
getToken()
getToken()
sign = -1
elsif Ch='*' then
getToken()
getToken()
sign = 0
else
exit
end if
end while
return res
end function
constant valid_ds_offsets = {0,4,8,12,16,20,24}
function findreg(integer rex)
-- factored out mainly for the error handling (eg [ebx+rax]), which I
-- for one tend to trip up on quite alot when converting 32 to 64bit.
integer res
if rex then
res = find(ttidx,R64)
else
res = find(ttidx,REG32)
end if
if res=0 then
if rex then
if find(ttidx,REG32) then
Aborp("invalid: mixed register size")
end if
else
if find(ttidx,R64) then
Aborp("invalid: mixed register size")
end if
end if
end if
return res
end function
--function get_mem(integer permitted, integer size)
function get_mem(integer permitted, integer size, bool bSet)
-- see get_operand. (factored out for "[]" and "dword[]" etc handling)
integer scale = 0
integer idx = 0
integer base = 0
integer offset = 0
integer N
sequence symtabN
object vtype
integer state
integer sType
integer lblidx
integer rex
if not and_bits(permitted,P_MEM) then
Aborp("not permitted")
end if
getCh()
getToken()
if toktype!=LETTER then
-- instead of [imm32] code (say) mov eax,imm32, ...[eax];
-- instead of [d8+reg] you must code [reg+d8]
Aborp("register or hllvar expected")
end if
rex = 0
base = find(ttidx,REG32)
if base=0 and Z64=1 then
base = find(ttidx,R64)
rex = #40
-- size = 8?
end if
if base!=0 then
if Ch='*' then -- [i*s+b]
idx = base
base = 0
getCh()
getToken()
if toktype!=DIGIT
or not find(TokN,{2,4}) then -- 8? [DEV]
Aborp("unrecognised")
end if
scale = TokN
if Ch!='+' then
Aborp("+ expected")
end if
getToken()
if Ch=':' then -- [i*s+:lbl] form (for jump tables)
if not and_bits(permitted,P_LBL) then
Aborp("not permitted")
end if
getCh()
tokline = line
tokcol = col
lblidx = il_search(':')
if lblidx then -- extend existing backpatch chain
Aborp("not permitted")
end if
-- start a new backpatch chain
lblchain = append(lblchain,0)
lblidx = length(lblchain)
lblpos = append(lblpos,-1)
lblopa = append(lblopa,-1)
lblline = append(lblline,tokline)
lblcol = append(lblcol,tokcol)
lblused = append(lblused,1)
lblttidx = append(lblttidx,ttidx)
tt[ttidx+EQ] = length(lblttidx)
if Ch!=']' then
Aborp("] expected")
end if
getToken()
-- return {P_MEM+P_LBL,size,{scale,idx,lblidx,rex}}
return {P_MEM+P_LBL,size,{scale,idx,lblidx}}
end if
getToken()
if toktype=LETTER then
-- base = find(ttidx,REG32)
-- if base=0 and Z64=1 then
-- base = find(ttidx,R64)
---- rex = ??
---- size = 8?
-- end if
base = findreg(rex)
end if
if base=0 then
Aborp("base register expected")
end if
elsif Ch='+' then
getToken()
getToken()
if toktype=LETTER then
-- idx = find(ttidx,REG32)
-- if idx=0 and Z64=1 then
-- idx = find(ttidx,R64)
---- rex = ??
---- size = 8?
-- end if
idx = findreg(rex)
if idx=0 then
offset = get_offset(0,1)
else --idx!=0
if Ch='*' then -- [b+i*s]
getToken()
getToken()
if toktype!=DIGIT
--4/9/14:
-- or not find(TokN,{2,4}) then --8?
or not find(TokN,{2,4,8}) then
Aborp("unrecognised")
end if
--if TokN=8 then trace(1) end if
scale = TokN
end if
end if
else
if toktype!=DIGIT then
Aborp("unrecognised")
end if
offset = TokN
end if
end if
if Ch='+' then
getToken()
getToken()
-- offset += get_offset(1)
offset = get_offset(offset,1)
elsif Ch='-' then
getToken()
getToken()
-- offset += get_offset(-1)
offset = get_offset(offset,-1)
elsif Ch='*' then
getToken()
getToken()
-- offset *= get_offset(1)
offset = get_offset(offset,0)
end if
if Ch!=']' then
Aborp("] expected")
end if
getToken()
-- return {P_MEM,size,{scale,idx,base,offset,rex}}
return {P_MEM,size,{scale,idx,base,offset}}
elsif ttidx=T_ds then
-- raw data section offsets:
-- [ds+0|4|8|12|16|20|24] (see valid_ds_offsets)
-- [ds+idx*scale+base+0|4|8|12|16|20|24]
if not newEmit then -- DEV temp
if intellisense=0 then
Aborp("not permitted (newEmit=0)")
end if
end if
if Ch!='+' then
Aborp("+ expected")
end if
getCh()
getToken()
if toktype=LETTER then
base = find(ttidx,REG32)
if base=0 and Z64=1 then
base = find(ttidx,R64)
rex = #40
end if
if base=0 then
Aborp("unrecognised")
end if
if Ch='*' then -- [i*s+n]
idx = base
base = 0
getCh()
getToken()
if toktype!=DIGIT
or not find(TokN,{2,4,8}) then
Aborp("unrecognised")
end if
scale = TokN
end if
if Ch='+' then
getCh()
getToken()
-- if toktype=LETTER then
--?9/0 --DEV this can be removed, I think... (only [ds+imm] allowed, for initStack/opRand only)
-- if base=0 then
---- base = find(ttidx,REG32)
---- if base=0 and Z64=1 then
---- base = find(ttidx,R64)
---- end if
-- base = findreg(rex)
-- if base=0 then
-- Aborp("unrecognised")
-- end if
-- else
---- idx = find(ttidx,REG32)
---- if idx=0 and Z64=1 then
---- idx = find(ttidx,R64)
---- end if
-- idx = findreg(rex)
-- if idx=0 then
-- Aborp("unrecognised")
-- end if
-- if Ch='*' then -- [i*s+n]
-- getCh()
-- getToken()
-- if toktype!=DIGIT
-- or not find(TokN,{2,4,8}) then
-- Aborp("unrecognised")
-- end if
-- scale = TokN
-- end if
-- end if
-- if Ch='+' then
-- getCh()
-- getToken()
-- if toktype!=DIGIT
-- or not find(TokN,valid_ds_offsets) then
-- Aborp("unrecognised")
-- end if
-- offset = TokN
-- end if
-- else
if toktype!=DIGIT
or not find(TokN,valid_ds_offsets) then
Aborp("unrecognised")
end if
offset = TokN
-- end if
end if
else
if toktype!=DIGIT
or not find(TokN,valid_ds_offsets) then
Aborp("unrecognised")
end if
offset = TokN
end if
if Ch!=']' then
Aborp("] expected")
end if
getToken()
-- return {P_RAW,size,{scale,idx,base,offset,rex}}
return {P_RAW,size,{scale,idx,base,offset}}
else
N = InTable(InAny)
if N<=0 then Undefined() end if
symtabN = symtab[N]
vtype = symtabN[S_vtype]
if not integer(vtype) then -- (ie a proc/func/type)
Aborp("illegal")
end if
state = symtabN[S_State]
if and_bits(state,K_Fres) then ?9/0 end if -- internal error
--DEV should set/used be a param [integer hllstateflag]? (spotted in passing) [done as bSet/K_asmm, 24/4/21]
-- if not and_bits(state,S_set) then
integer mask = iff(bSet ? S_set+K_asmm : S_set)
if and_bits(state,mask)!=mask then
-- state += S_set
state = or_bits(state,mask)
symtab[N] = 0 -- kill refcount
symtabN[S_State] = state
symtab[N] = symtabN
end if
sType = symtabN[S_NTyp]
if emitON then
if sType=S_GVar2 then -- or Const?
SideEffects = or_bits(SideEffects,power(2,remainder(N,29)))
elsif sType=S_TVar then
lMask = or_bits(lMask,power(2,remainder(N,29)))
end if
end if
if Ch!=']' then
Aborp("] expected")
end if
getToken()
if size=0 then -- added 27/8/14
size = 4
if X64 then
size = 8
end if
end if
return {P_VAR,size,{N,sType}}
end if
end function
tt_string("dword",-3)
constant Z_dword = ttidx -- Allows us to pretend we found T_dword when using
-- the wrong (label) terminator. For jmp dword[sib].
tt_string("qword",-3)
constant Z_qword = ttidx -- ditto, but for jmp qword[sib]
-- Sigh. As soon as I said that was it... Nevermind (small price to pay really)
tt_string("eax",-3) constant Z_eax = ttidx
tt_string("ecx",-3) constant Z_ecx = ttidx
tt_string("edx",-3) constant Z_edx = ttidx
tt_string("ebx",-3) constant Z_ebx = ttidx
tt_string("esp",-3) constant Z_esp = ttidx
tt_string("ebp",-3) constant Z_ebp = ttidx
tt_string("esi",-3) constant Z_esi = ttidx
tt_string("edi",-3) constant Z_edi = ttidx
constant REZ32 = {Z_eax,Z_ecx,Z_edx,Z_ebx,Z_esp,Z_ebp,Z_esi,Z_edi}
tt_string("rax",-3) constant Z_rax = ttidx
tt_string("rcx",-3) constant Z_rcx = ttidx
tt_string("rdx",-3) constant Z_rdx = ttidx
tt_string("rbx",-3) constant Z_rbx = ttidx
tt_string("rsp",-3) constant Z_rsp = ttidx
tt_string("rbp",-3) constant Z_rbp = ttidx
tt_string("rsi",-3) constant Z_rsi = ttidx
tt_string("rdi",-3) constant Z_rdi = ttidx
tt_string("r8" ,-3) constant Z_r8 = ttidx
tt_string("r9" ,-3) constant Z_r9 = ttidx
tt_string("r10",-3) constant Z_r10 = ttidx
tt_string("r11",-3) constant Z_r11 = ttidx
tt_string("r12",-3) constant Z_r12 = ttidx
tt_string("r13",-3) constant Z_r13 = ttidx
tt_string("r14",-3) constant Z_r14 = ttidx
tt_string("r15",-3) constant Z_r15 = ttidx
constant REZ64 = {Z_rax,Z_rcx,Z_rdx,Z_rbx,Z_rsp,Z_rbp,Z_rsi,Z_rdi,Z_r8,Z_r9,Z_r10,Z_r11,Z_r12,Z_r13,Z_r14,Z_r15}
-- <aside>
-- A full explanation of why we need/have both T_xxx and Z_xxx is quite
-- tedious and not really very interesting. Feel free to skip this note.
-- The bulk of the T_xxx live in the main (terminator -2) table and do
-- *NOT* store anything in tt[ttidx+EQ], so will not interfere with the
-- outside world (hll) in any way, shape, or form. And we can still use
-- getToken() etc with all the added (esp number) goodness that has, and
-- indeed reference hll variables and constants just like normal, with
-- all the proper scope rules (using the standard InTable(InAny)) etc.
-- However ilASM labels /DO/ need to store an idx in tt[ttidx+EQ] and
-- hence live in a "separate" (terminator -3) table (ie they share the
-- letters but end differently). Now, because we want eg "jmp lbl" to
-- behave as "jmp :lbl", we /MUST/ il_search (which goes -3) but a
-- couple of minor cases (jmp dword[], jmp ecx) have wandered off down
-- the wrong tree (for T_xxx constant use). Maybe we could reset col
-- and run both, or ...nah: just add the Z_s. Told you it was boring.
-- </aside>
--with trace
function get_label()
-- factored out code for get_operand() and jcc()
integer lblidx
integer reg
integer k, gflags
-- if Ch='%' then -- global label
k = find(Ch,"%!>")
if k!=0 then -- global label
tokline = line
tokcol = col
lblidx = il_search(':')
if emitON then -- added 10/10/14
if lblidx then
if lblidx>length(glblused) then
Aborq("label index error")
end if
if not and_bits(glblused[lblidx],G_used) then
glblused[lblidx] += G_used
end if
else
-- glblused = append(glblused,G_used)
gflags = G_used
if k=2 then
gflags += G_bang
elsif k=3 then
gflags += G_init
end if
glblused = append(glblused,gflags)
glboffset = append(glboffset,0)
-- glbttidx = append(glbttidx,ttidx)
glblabel = append(glblabel,fileno)
glblline = append(glblline,tokline)
glblcol = append(glblcol,tokcol)
glblname = append(glblname,"??("&text[tokcol..col-1]&")")
lblidx = length(glblused)
tt[ttidx+EQ] = lblidx
--?{ttidx,glttidxTestM}
--if ttidx=glttidxTestM then trace(1) end if
agchecktt(ttidx)
end if
end if
return {P_GBL,0,lblidx}
else -- (local label)
tokline = line
tokcol = col
if Ch=':' then Aborp("cannot define a new label here") end if
lblidx = il_search(':')
--?{"get_label",lblidx,ttidx,tokcol}
-- if ttidx=Z_dword then -- (as T_dword but -3 terminator)
if ttidx=Z_dword -- (as T_dword but -3 terminator)
or ttidx=Z_qword then
skipSpacesAndComments()
if Ch!='[' then
Expected("'['")
end if
-- return get_mem(P_MEM,0)
return get_mem(P_MEM,0,false)
end if
reg = find(ttidx,REZ32)
if reg then
return {P_REG,4,reg}
end if
if Z64=1 then
reg = find(ttidx,REZ64)
if reg then
return {P_REG,8,reg}
end if
end if
if emitON then -- added 10/10/14
if lblidx then -- extend existing backpatch chain
if lblidx<=0 or lblidx>length(lblttidx) then
Aborp("bad lblidx (bug in phix)")
end if
if ttidx!=lblttidx[lblidx] then ?9/0 end if -- sanity check
else -- start a new backpatch chain
lblchain = append(lblchain,0)
lblidx = length(lblchain)
lblpos = append(lblpos,-1)
lblopa = append(lblopa,-1)
lblline = append(lblline,tokline)
lblcol = append(lblcol,tokcol)
lblused = append(lblused,1)
lblttidx = append(lblttidx,ttidx)
tt[ttidx+EQ] = length(lblttidx)
end if
end if
return {P_LBL,0,lblidx}
end if
end function
--function get_operand(integer permitted)
function get_operand(integer permitted, bool bSet)
--
-- Get an operand, allowed permission bits of:
-- P_REG (#01): reg32, (implies dword)
-- reg8, (implies byte)
-- details returned: 1..8 (nb not 0..7)
-- P_MEM (#02): [hllvar] (implies dword) -- returns P_VAR
-- [reg]
-- [reg+d8]
-- [reg+d32]
-- [b+i*s]
-- [b+i*s+d8]
-- [b+i*s+d32]
-- [i*s+b]
-- [i*s+b+d8]
-- [i*s+b+d32]
-- (optionally preceded by a size)
-- (d8/d32 may be hll constants and literal ints with
-- simple +/- resolvable at compile-time, eg BUFF-1)
-- details returned (PMEM): {scale,idx,base,offset}
-- (note that idx,base are 1..8 not 0..7)
-- details returned (P_VAR): {N,sType}
-- P_LBL (#04): :label
-- :%glbl -- returns P_GBL
-- (opCodes and dll entry points handled elsewhere)
-- details returned: lblidx (and a size of 0)
-- P_IMM (#08): imm8 (may be a hll or char constant)
-- imm16 (may be a hll const)
-- imm32 (may be a hll const)
-- h4 (same as "#40000000")
-- (optionally preceded by a size)
-- (simple +/-/* allowed, if resolveable at compile-time)
-- details returned: atom (-#80000000..0..+#FFFFFFFF)
-- P_SEG (#40): fs:[imm32] or fs:[reg] for tls handling
-- P_FPU (#80): st0..st7 (etc?)
--
-- Returns a {type,size,details} triplet, where type is one of the six
-- P_XXX values above (ie P_REG/P_MEM/P_VAR/P_LBL/P_GBL/P_IMM),
-- size is 0/1/2/4/8, and details depends on type, as above.
--
integer size = 0
integer reg
integer N
sequence symtabN
integer vtype
atom res
integer state
skipSpacesAndComments()
if Ch='[' then
return get_mem(permitted,0,bSet)
end if
if Ch=':' then
if not and_bits(permitted,P_LBL) then
Aborp("not permitted")
end if
getCh()
return get_label()
end if
getToken()
if toktype=LETTER then
size = find(ttidx,SIZES)
if size!=0 then
if ttidx=T_tword then
Aborp("I think you mean tbyte")
end if
size = SIZE[size]
skipSpacesAndComments()
if Ch='[' then
return get_mem(permitted,size,bSet)
end if
getToken()
else
--hmm, if (not elsif, see P_XMM!) and_bits(permitted,P_REG) then?
reg = find(ttidx,REG32)
if reg!=0 then
return {P_REG,4,reg}
end if
reg = find(ttidx,REG16)
if reg!=0 then
return {P_REG,2,reg}
end if
reg = find(ttidx,REG8)
if reg!=0 then
return {P_REG,1,reg}
end if
if Z64=1 then
reg = find(ttidx,R64)
if reg!=0 then
-- rex = ??
-- size = 8?
return {P_REG,8,reg}
end if
reg = find(ttidx,R32)
if reg!=0 then
-- rex = ??
-- size = 8?
return {P_REG,4,reg+8}
end if
reg = find(ttidx,R16)
if reg!=0 then
-- rex = ??
-- size = 8?
return {P_REG,2,reg+8}
end if
reg = find(ttidx,R8l)
if reg!=0 then
-- rex = ??
-- size = 8?
return {P_REG,1,reg+8}
end if
reg = find(ttidx,R8b)
if reg!=0 then
-- rex = ??
-- size = 8?
return {P_REG,1,reg+4}
end if
end if
if and_bits(permitted,P_FPU) then
reg = find(ttidx,FREG)
if reg!=0 then
return {P_FPU,0,reg}
end if
end if
if and_bits(permitted,P_XMM) then
reg = find(ttidx,XMM)
if reg!=0 then
return {P_XMM,0,reg}
end if
end if
end if
end if
if toktype=LETTER then
if ttidx=T_h4 then
TokN = #40000000
elsif ttidx=T_fs then
if not and_bits(permitted,P_SEG) then
Aborp("not permitted")
end if
--DEV (spotted/added in passing)
if size!=0 and size!=4 then Abort("invalid") end if
if Ch!=':' then
Aborp(": expected")
end if
getCh()
if Ch!='[' then
Aborp("[ expected")
end if
getCh()
getToken()
if toktype=LETTER then
reg = find(ttidx,REG32)
if reg=0 and Z64=1 then
reg = find(ttidx,R64)
-- rex = ??
-- size = 8?
end if
if reg=0 then
Aborp("reg expected")
end if
else
if toktype=FLOAT
and (TokN==and_bits(TokN,#FFFFFFFF) or
(TokN-#100000000)==and_bits(TokN,#FFFFFFFF)) then -- (-#1,0000,0000 maps large values #80000000..#FFFFFFFF to their -ve bit-identical equivalents)
toktype = DIGIT
end if
if toktype!=DIGIT then
Aborp("reg or imm32 expected")
end if
end if
if Ch!=']' then
Aborp("] expected")
end if
getCh()
if toktype=LETTER then
return {P_SEG,4,{P_REG,T_fs,reg}}
else
return {P_SEG,4,{P_IMM,T_fs,TokN}}
end if
else
N = InTable(InAny)